Script to generate a table of contents. Supports long documents.

There are a few great scripts out there that automatically create a table of contents for your OmniGraffle document.

This script does as well, but it will spread the table of contents over multiple pages if necessary, and it will also list section headers if you have canvases within your document that serve as section header pages.

It's also extremely customizable.You can pretty much make it look exactly like you want it to look, and you have precise control over almost every aspect of it by changing the properties listed at the top of the script that start with the prefix "SETTINGS_".

Here is one example of how the table of contents for a document with section headings might look, but again, you can customize it to look any number of ways.

The script currently has these limitations.

• It does not gracefully support wrapping long canvas names; if a canvas name is so long it wraps, it's not going to look great.
• Sections (the section header and its child pages) have no way to alter the default widow/orphan control. A section is alway kept together unless its height is greater than the canvas height

If additional table-of-content pages are required due to the document being too long to display the TOC on a single canvas, additional canvases will be created to accommodate additional TOC pages. Note: these will be placed at the front of the document and you will have to move them manually due to a bug in OmniGraffle's AppleScript implementation related to moving canvases. (That bug is explained in a post here.)

The script is after the jump. Copy it and paste it into AppleScript editor and run it.

I'm hoping the comments in the script are sufficient to describe the various customizable options. If you have any questions or find any bugs, or you want any new features, please leave a comment.

-- Copyright © 2013, Joseph Brick
-- All rights reserved. 
-- Redistribution, with or without modification, is permitted provided that the copyright notice is retained.

-- Details on this script can be found here: 
-- http://omnigraffletips.blogspot.com/2013/06/script-to-generate-table-of-contents.html

-- Settings for the TOC as a whole:  
property SETTINGS_warnOnMultiPageTOC : true --Warns before adding additional canvases (if table of contents won't fit on one canvas)
property SETTINGS_tocOuterMargins : {40, 55, 40, 30} -- margin between the TOC and the edge of the canvas: {left, top, right, bottom}
property SETTINGS_tocPage : 2 -- canvas on which the table of contents will be created. Create this canvas before running the script.
property SETTINGS_tocNumColumns : 2 -- number of columns per TOC canvas
property SETTINGS_tocColSpacing : 50 -- spacing between columns

-- Settings for each TOC item
property SETTINGS_itemHeight : 26 --height of a TOC item
-- font settigs for canvas name and page number
property SETTINGS_itemFontFace : "Helvetica"
property SETTINGS_itemFontSize : 16
property SETTINGS_itemFontColor : {0.3, 0.3, 0.3}
property SETTINGS_itemVerticalTextPlacement : "center" -- Vertical placement within item: "top", "bottom", "center"
property SETTINGS_itemTopBottomTextPadding : 0 --applies if SETTINGS_itemVerticalTextPlacement is "top" or "bottom" - rounds to nearest integer
-- page number settings
property SETTINGS_showItemPageNumber : true
property SETTINGS_itemPageNumberLoc : "delimited" -- values: "right" or "delimited"; if "right" the page number is right-justified; if "delimited" the canvas name and page number has a text string between it.
property SETTINGS_itemPageNumberRightPadding : 0 -- if SETTINGS_itemPageNumberLoc is "right" this is the padding between the page number and the right side of the TOC item. Supports real numbers.
property SETTINGS_itemPageNumberDelimiter : "    " -- text string that goes between the canvas name and page number if SETTINGS_itemPageNumberLoc is "delimited"
property SETTINGS_italicizeItemPageNumber : true
-- line settings
property SETTINGS_drawLineBelowItem : false
property SETTINGS_itemLineThickness : 1.5
property SETTINGS_itemLineColor : {0.4, 0.4, 0.4}
property SETTINGS_itemLineBottomPadding : 0 -- supports real numbers 

-- All settings below define section-heading items in the TOC.
-- if you want section headings listed, set SETTINGS_useSections to true and put a shared layer called "Section Title" on each of your section header pages.
-- (You can have SETTINGS_useSections set to true even if you don't have section header pages, but the script will run slower.)

property SETTINGS_useSections : false
property SETTINGS_sectionItemHeight : 50 -- Height of a section heading TOC item.
property SETTINGS_sectionItemChildIndent : 0 -- Amount child pages of the section heading are indented; supports real numbers.
-- section font settigs for canvas name and page number
property SETTINGS_sectionItemFontFace : "Helvetica"
property SETTINGS_sectionItemFontSize : 18
property SETTINGS_sectionItemFontColor : {0.1, 0.1, 0.1}
property SETTINGS_sectionItemVerticalTextPlacement : "bottom" -- Vertical placement within item: "top", "bottom", "center"
property SETTINGS_sectionItemTopBottomTextPadding : 10 --applies if SETTINGS_sectionItemVerticalTextPlacement is "top" or "bottom"; supports integers.
-- section page number settings
property SETTINGS_showSectionItemPageNumber : true
property SETTINGS_sectionItemPageNumberLoc : "right" --values: "right" or "delimited"
property SETTINGS_SectionItemPageNumberRightPadding : 0 -- if SETTINGS_SectintemPageNumberLoc is "right" this is the padding between the page number and the right side of the TOC item
property SETTINGS_sectionItemPageNumberDelimiter : "    " --text string between name and page numbeer if SETTINGS_sectionItemPageNumberLoc is "delimited"
property SETTINGS_italicizeSectionItemPageNumber : false
-- section line settings
property SETTINGS_drawLineBelowSectionItem : true
property SETTINGS_sectionItemLineThickness : 1.5
property SETTINGS_sectionItemLineColor : {0.8, 0.8, 0.8}
property SETTINGS_sectionItemLineBottomPadding : 5

------------------

property statusWindow : {}

on run
    tell application id "OGfl"
        tell front document
            set curCanvas to item SETTINGS_tocPage of canvases
            set docCanvasSize to canvasSize of (curCanvas)
            set tocSize to {(item 1 of docCanvasSize) - (item 1 of SETTINGS_tocOuterMargins) - (item 3 of SETTINGS_tocOuterMargins), (item 2 of docCanvasSize) - (item 2 of SETTINGS_tocOuterMargins) - (item 4 of SETTINGS_tocOuterMargins)}
            set colWidth to (item 1 of tocSize) / SETTINGS_tocNumColumns - ((SETTINGS_tocNumColumns - 1) * SETTINGS_tocColSpacing) / SETTINGS_tocNumColumns
            set columnData to {}
            set xLoc to item 1 of SETTINGS_tocOuterMargins
            repeat with i from 1 to SETTINGS_tocNumColumns
                set end of columnData to {xLoc:xLoc, colWidth:colWidth}
                set xLoc to xLoc + colWidth + SETTINGS_tocColSpacing
            end repeat
            set canvasCount to (count canvases) - SETTINGS_tocPage
            set allTocGroups to getGroups(canvases, item 2 of tocSize, curCanvas) of me
            set totalColumns to columnNum of last item of allTocGroups
            set numPages to totalColumns div SETTINGS_tocNumColumns
            if totalColumns / SETTINGS_tocNumColumns > totalColumns div SETTINGS_tocNumColumns then
                set numPages to numPages + 1
            end if
            set dialogRetVal to "Add Canvases"
            if numPages > 1 and SETTINGS_warnOnMultiPageTOC then
                set msg to "This table of contents won't fit on a single canvas. Add canvases to accommodate table of contents?\n\n(These will be added to beginning of the document; you'll need to move them after your current table-of-contents canvas.)"
                set dialogRetVal to display dialog msg buttons {"Add Canvases", "Quit"} default button "Add Canvases"
                set dialogRetVal to button returned of dialogRetVal
            end if
            if dialogRetVal is "Add Canvases" then
                set tocCanvases to {}
                repeat with i from 1 to numPages - 1
                    set c to make new canvas at beginning of canvases
                    set name of c to name of curCanvas & " page " & (numPages - i + SETTINGS_tocPage - 1)
                    set canvasSize of c to canvasSize of curCanvas
                    set beginning of tocCanvases to c
                end repeat
                set beginning of tocCanvases to curCanvas
                repeat with curGroup in allTocGroups
                    get drawColumns(curGroup, columnData, tocCanvases, canvasCount) of me
                end repeat
                get closeStatusWindow() of me
            end if
        end tell
    end tell
end run

on drawColumns(tocGroup, columnData, tocCanvases, canvasCount)
    tell application id "OGfl"
        set colNum to (columnNum of tocGroup) mod SETTINGS_tocNumColumns
        set pageOffset to (count tocCanvases) - 1
        if colNum = 0 then
            set colNum to SETTINGS_tocNumColumns
        end if
        set curDatum to item colNum of columnData
        set xLoc to xLoc of curDatum
        set yloc to item 2 of SETTINGS_tocOuterMargins
        set graphicList to {}
        set curPageNum to (columnNum of tocGroup) div SETTINGS_tocNumColumns
        if ((columnNum of tocGroup) / SETTINGS_tocNumColumns) > ((columnNum of tocGroup) div SETTINGS_tocNumColumns) then
            set curPageNum to curPageNum + 1
        end if
        set curCanvas to item curPageNum of tocCanvases
        tell curCanvas
            set tocItems to tocItems of tocGroup
            set yloc to yloc + (groupYLoc of tocGroup)
            repeat with curTocItem in tocItems
                get showStatus((tocPageNum of curTocItem) - SETTINGS_tocPage, canvasCount, "Drawing Table of Contents") of me
                set end of graphicList to drawItem(curTocItem, {xLoc, yloc}, colWidth of curDatum, curCanvas, pageOffset) of me
                set yloc to yloc + (tocItemHeight of curTocItem)
            end repeat
            if (count graphicList) > 1 then
                assemble graphicList
            end if
        end tell
    end tell
end drawColumns

on drawItem(tocItem, tocItemLoc, colWidth, canvasRef, pageOffset)
    set itemData to {}
    if SETTINGS_useSections and isTocSection of tocItem then
        set itemData to {textPlacement:SETTINGS_sectionItemVerticalTextPlacement, verticalPadding:SETTINGS_sectionItemTopBottomTextPadding, fontFace:SETTINGS_sectionItemFontFace, fontSize:SETTINGS_sectionItemFontSize, fontColor:SETTINGS_sectionItemFontColor, drawPageNumber:SETTINGS_showSectionItemPageNumber, pageNumberLoc:SETTINGS_sectionItemPageNumberLoc, pageNumberRightPadding:SETTINGS_SectionItemPageNumberRightPadding, pageNumberDelimiter:SETTINGS_sectionItemPageNumberDelimiter, italicizeNumber:SETTINGS_italicizeSectionItemPageNumber, drawLine:SETTINGS_drawLineBelowSectionItem, lineThickness:SETTINGS_sectionItemLineThickness, lineColor:SETTINGS_sectionItemLineColor, lineOffset:SETTINGS_sectionItemLineBottomPadding}
        else
            if SETTINGS_useSections then
                set item 1 of tocItemLoc to (item 1 of tocItemLoc) + SETTINGS_sectionItemChildIndent
                set colWidth to colWidth - SETTINGS_sectionItemChildIndent
            end if
            set itemData to {textPlacement:SETTINGS_itemVerticalTextPlacement, verticalPadding:SETTINGS_itemTopBottomTextPadding, fontFace:SETTINGS_itemFontFace, fontSize:SETTINGS_itemFontSize, fontColor:SETTINGS_itemFontColor, drawPageNumber:SETTINGS_showItemPageNumber, pageNumberLoc:SETTINGS_itemPageNumberLoc, pageNumberRightPadding:SETTINGS_itemPageNumberRightPadding, pageNumberDelimiter:SETTINGS_itemPageNumberDelimiter, italicizeNumber:SETTINGS_italicizeItemPageNumber, drawLine:SETTINGS_drawLineBelowItem, lineThickness:SETTINGS_itemLineThickness, lineColor:SETTINGS_itemLineColor, lineOffset:SETTINGS_itemLineBottomPadding}
    end if
    tell application id "OGfl"
        set g to {}
        tell canvasRef
            if drawPageNumber of itemData = true and pageNumberLoc of itemData = "right" then
                set end of g to make new shape at end of graphics with properties {draws shadow:false, size:{colWidth - (pageNumberRightPadding of itemData), tocItemHeight of tocItem}, text:{text:((tocPageNum of tocItem) + pageOffset) as text, size:fontSize of itemData, font:fontFace of itemData, color:fontColor of itemData, alignment:right}, origin:tocItemLoc, draws stroke:false, fill color:{1.0, 1.0, 1.0, 0.0}, text placement:SETTINGS_itemVerticalTextPlacement, vertical padding:verticalPadding of itemData}
                if textPlacement of itemData = "top" then
                    set text placement of last item of g to top
                else if textPlacement of itemData = "bottom" then
                    set text placement of last item of g to bottom
                else
                    set text placement of last item of g to center
                end if
            end if
            set txt to tocItemName of tocItem
            if drawPageNumber of itemData and pageNumberLoc of itemData = "delimited" then
                set txt to txt & pageNumberDelimiter of itemData & (tocPageNum of tocItem) + pageOffset
            end if
            set end of g to make new shape at end of graphics with properties {draws shadow:false, size:{colWidth, tocItemHeight of tocItem}, text:{text:txt, size:fontSize of itemData, font:fontFace of itemData, color:fontColor of itemData, alignment:left}, origin:tocItemLoc, draws stroke:false, fill color:{1.0, 1.0, 1.0, 0.0}, text placement:SETTINGS_itemVerticalTextPlacement, vertical padding:verticalPadding of itemData}
            if textPlacement of itemData = "top" then
                set text placement of last item of g to top
            else if textPlacement of itemData = "bottom" then
                set text placement of last item of g to bottom
            else
                set text placement of last item of g to center
            end if
            if drawLine of itemData then
                set end of g to make new line at end of graphics with properties {point list:{{item 1 of tocItemLoc, (item 2 of tocItemLoc) + (tocItemHeight of tocItem) - (lineOffset of itemData)}, {(item 1 of tocItemLoc) + colWidth, (item 2 of tocItemLoc) + (tocItemHeight of tocItem) - (lineOffset of itemData)}}, stroke cap:butt, stroke color:lineColor of itemData, thickness:lineThickness of itemData}
            end if
            if drawPageNumber of itemData and italicizeNumber of itemData then
                italicize last word of text of first item of g
            end if
            set jump of first item of g to canvasRef of tocItem
        end tell
        if (count g) > 1 then
            return assemble g
        else
            return item 1 of g
        end if
    end tell
end drawItem

(*
This returns data necessary to create all toc-items and pages. 
A "group" is is an element that stacks within a column:
If hasSections is false, each group in the list returned contains the max amount of toc-items that fit between the top and bottom margins. (In this case, a group is the same as a column.)
If hasSections is true, each group contains the section header and all of its children. 
Either way, each group in the returned list of groups is a record that contains the group's column number, the number of toc-items in that group, and a list of records that each represent a toc-item in that group. 
Each toc-item record has the associated canvas name, the toc-item height, whether it is a section header, and the associated canvas reference
*)
on getGroups(canvasList, tocHeight, canvasRef)
    set tocGroupList to {}
    set curTocItems to {}
    set totalHeight to 0
    set tocItemCount to 0
    set isNextTocItemSection to false
    set isCurItemSection to false
    set curTocItemHeight to SETTINGS_itemHeight
    set curFontSize to 0
    tell application id "OGfl"
        set canvasCount to count canvasList
        repeat with i from SETTINGS_tocPage + 1 to canvasCount
            get showStatus(i - SETTINGS_tocPage, canvasCount - SETTINGS_tocPage, "Calculating layout…") of me
            set curCanvas to item i of canvasList
            if SETTINGS_useSections then
                set isCurItemSection to isSection(curCanvas) of me
            end if
            if isCurItemSection then
                set curTocItemHeight to SETTINGS_sectionItemHeight
                set curFontSize to SETTINGS_sectionItemFontSize
            else
                set curTocItemHeight to SETTINGS_itemHeight
                set curFontSize to SETTINGS_itemFontSize
            end if
            if SETTINGS_useSections then
                set isNextTocItemSection to (i < canvasCount and isSection(item (i + 1) of canvasList) of me)
            end if
            set totalHeight to totalHeight + curTocItemHeight
            set tocItemCount to tocItemCount + 1
            set curItem to {tocItemName:name of curCanvas, tocPageNum:i, tocItemHeight:curTocItemHeight, fontSize:curFontSize, isTocSection:isCurItemSection, canvasRef:curCanvas}
            set end of curTocItems to curItem
            if (totalHeight + SETTINGS_itemHeight) > tocHeight or isNextTocItemSection then --close this group
                set end of tocGroupList to {columnNum:0, groupYLoc:0, columnHeight:totalHeight, numTocItems:tocItemCount, tocItems:curTocItems}
                set totalHeight to 0
                set tocItemCount to 0
                set curTocItems to {}
            end if
        end repeat
        if (count curTocItems) > 0 then
            set end of tocGroupList to {columnNum:0, groupYLoc:0, columnHeight:totalHeight, numTocItems:tocItemCount, tocItems:curTocItems}
        end if
        --Assign columns to groups
        set colCount to 1
        set colHeight to 0
        set groupCount to count tocGroupList
        repeat with i from 1 to groupCount
            set curGroup to item i of tocGroupList
            set groupYLoc of curGroup to colHeight
            set colHeight to colHeight + (columnHeight of curGroup)
            set columnNum of curGroup to colCount
            if i < groupCount then
                set nextHeight to columnHeight of item (i + 1) of tocGroupList
                if (colHeight + nextHeight) > tocHeight then
                    set colCount to colCount + 1
                    set colHeight to 0
                end if
            end if
        end repeat
    end tell
    get closeStatusWindow()
    return tocGroupList
end getGroups

-- displays progress
on showStatus(i, totalItems, message)
    tell application id "OGfl"
        set statusThreshold to 15
            if (count statusWindow) = 0 then
            set statusWindow to {dialogBack:"", statusText:"", sliderBack:"", sliderProgress:""}
            if totalItems > statusThreshold then
                set canvasRef to canvas of front window
                set statusWindowSize to {200, 90}
                set cSize to canvasSize of canvasRef
                set statusWindowLoc to {((item 1 of cSize) - (item 1 of statusWindowSize)) / 2, ((item 2 of cSize) - (item 2 of statusWindowSize)) / 2}
                set statusWindowSize to {200, 90}
                set g to {}
                tell canvasRef
                    set dialogBack of statusWindow to make new shape at beginning of graphics with properties {size:statusWindowSize, origin:statusWindowLoc, text:{text:message, size:14, alignment:left}, side padding:10, text placement:top, vertical padding:10, stroke color:{0, 0, 0}, fill color:{1, 1, 1}, draws shadow:true, alignment:right}
                    set statusText of statusWindow to make new shape at beginning of graphics with properties {size:{(item 1 of statusWindowSize) - 20, 20}, origin:{(item 1 of statusWindowLoc) + 10, (item 2 of statusWindowLoc) + 45}, side padding:0, fill:no fill, draws stroke:false, draws shadow:false, autosizing:clip, text:{text:"", size:13}, text placement:top, vertical padding:0}
                    set sliderProgress of statusWindow to make new shape at beginning of graphics with properties {size:{1, 15}, origin:{(item 1 of statusWindowLoc) + 10, (item 2 of statusWindowLoc) + 65}, draws stroke:false, draws shadow:false, fill color:{0.8, 0.8, 0.8}}
                    set sliderBack of statusWindow to make new shape at beginning of graphics with properties {size:{(item 1 of statusWindowSize) - 20, 15}, origin:{(item 1 of statusWindowLoc) + 10, (item 2 of statusWindowLoc) + 65}, fill:no fill, draws shadow:false, stroke color:{0, 0, 0}}
                end tell
            end if
        end if
        if totalItems > statusThreshold then
            if i mod (totalItems div 13) = 0 or i = totalItems then
                set size of sliderProgress of statusWindow to {i / totalItems * 180, 15}
                set text of statusText of statusWindow to {text:"TOC item " & i & " of " & totalItems, size:13}
            end if
        end if
    end tell
end showStatus

-- removes the status window
on closeStatusWindow()
    tell application id "OGfl"
        if (count of statusWindow) is not 0 then
            delete sliderProgress of statusWindow
            delete sliderBack of statusWindow
            delete statusText of statusWindow
            delete dialogBack of statusWindow
            set statusWindow to {}
        end if
    end tell
end closeStatusWindow

-- checks to see if a canvas is a section header by inspecting the names of its shared layers. 
-- Only called when SETTINGS_UseSections is set to true
on isSection(c)
    tell application id "OGfl"
        set layerList to layers of c whose class is shared layer
        repeat with curLayer in layerList
            if name of curLayer is "Section Title" then
                return true
            end if
        end repeat
        return false
    end tell
end isSection